优化自动引用ADO、DAO、Excel -KevinFan
Access软件网QQ交流学习群(群号码198465573),欢迎您的加入!
首页 >技术文章> Access数据库-模块/函数/VBA


优化自动引用ADO、DAO、Excel

发表时间:2018/1/17 14:32:37 评论(2) 浏览(8176)  评论 | 加入收藏 | 复制
   
摘 要:由于不同电脑的系统环境(操作系统、Office版本)不一致,需要根据系统环境,在程序打开时自动重新引用ADO、DAO、Excel等
正 文:

由于不同电脑的系统环境(操作系统、Office版本)不一致,需要根据系统环境,在程序打开时自动重新引用ADO、DAO、Excel,之前参考论坛示例,整理了自动引用ADO、DAO、Excel的文章(原文章:http://www.accessoft.com/article-show.asp?id=16886),后来网友@lvxin5635评价说获取Office安装路径的方式更好,今天抽空查阅了论坛的资料,使用获取Office安装目录的方式来判断Excel的引用路径,代码如下(复制黏贴到模块):

Function FileExists(ByVal strFile As String, Optional bFindFolders As Boolean) As Boolean
    Dim lngAttributes As Long
    lngAttributes = (vbReadOnly or vbHidden or vbSystem)

    If bFindFolders Then
        lngAttributes = (lngAttributes or vbDirectory)
    Else
        Do While Right$(strFile, 1) = "\"
            strFile = Left$(strFile, Len(strFile) - 1)
        Loop
    End If

    On Error Resume Next
    FileExists = (Len(Dir(strFile, lngAttributes)) > 0)
End Function

Function FolderExists(strPath As String) As Boolean
    On Error Resume Next
    FolderExists = ((GetAttr(strPath) And vbDirectory) = vbDirectory)
End Function

Public Function ReAddADO()
    On Error Resume Next
    Dim strMDE As String: strMDE = CurrentDb.Properties("MDE")
    If strMDE = "T" Then Exit Function

    Dim REFE As References    '声明REFE为引用
    Dim strFileName As String    '声明strFileName为文本型变量
    Dim rf
    Set REFE = Application.References
    For Each rf In REFE    '在引用中循环查找
        If rf.Name = "ado" Then    '如果名字为ADO就移动ADO的引用
            Application.References.Remove rf    '移除
            Exit For    '退出循环
        End If
    Next

    If FolderExists("C:\Windows\SysWOW64") Then   '如果是64位操作系统
        strFileName = "C:\Program Files (x86)\Common Files\System\ado\msado15.dll"
    Else   '如果是32位操作系统
        strFileName = "C:\Program Files\Common Files\System\ado\msado15.dll"
    End If

    Set rf = Application.References.AddFromFile(strFileName)    '重新引用ADO

End Function

Public Function ReAddDAO()
    On Error Resume Next
    Dim strMDE As String: strMDE = CurrentDb.Properties("MDE")
    If strMDE = "T" Then Exit Function

    Dim REFE As References    '声明REFE为引用
    Dim strFileName As String    '声明strFileName为文本型变量
    Dim rf
    Set REFE = Application.References
    For Each rf In REFE    '在引用中循环查找
        If rf.Name = "DAO" Then    '如果名字为DAO就移动DAO的引用
            Application.References.Remove rf    '移除
            Exit For    '退出循环
        End If
    Next

    If FolderExists("C:\Windows\SysWOW64") Then    '如果是64位操作系统
        strFileName = "C:\Program Files (x86)\Common Files\microsoft shared\DAO\dao360.dll"
    Else   '如果是32位操作系统
        strFileName = "C:\Program Files\Common Files\Microsoft Shared\DAO\dao360.dll"
    End If

    Set rf = Application.References.AddFromFile(strFileName)    '重新引用DAO

End Function

Public Function ReAddExcel()
    On Error Resume Next
    Dim strMDE As String: strMDE = CurrentDb.Properties("MDE")
    If strMDE = "T" Then Exit Function

    Dim REFE As References    '声明REFE为引用
    Dim strFileName As String    '声明strFileName为文本型变量
    Dim rf
    Set REFE = Application.References
    For Each rf In REFE    '在引用中循环查找
        If rf.Name = "Excel" Then    '如果名字为Excel就移动Excel的引用
            Application.References.Remove rf    '移除
            Exit For    '退出循环
        End If
    Next

    strFileName = SysCmd(acSysCmdAccessDir) & "EXCEL.EXE"   '获取Access安装目录,也就是Office安装目录
    Debug.Print strFileName
    Set rf = Application.References.AddFromFile(strFileName)    '自动引用Excel

End Function


Access软件网交流QQ群(群号:198465573)
 
 相关文章
【Access懒人工具】用VBA代码重新引用DAO  【Bobby  2013/11/25】
【Access懒人工具】用VBA代码重新引用ADO  【麥田  2013/12/5】
【Access懒人工具】用VBA代码自动引用树控件|代码引用Mic...  【麥田  2013/12/6】
【Access懒人工具】用VBA代码自动引用OLE项|代码引用OL...  【麥田  2013/12/7】
【Access懒人工具】用VBA代码自动引用Excel项  【麥田  2016/9/19】
自动引用ADO、DAO、Excel  【KevinFan  2017/12/18】
常见问答
技术分类
相关资源
文章搜索
关于作者

KevinFan

文章分类

文章存档

友情链接