Toolbar 控件示例

该示例用 Add 方法将 Button 对象添加到 Toolbar 控件中去，并分配 ImageList 控件所提供的图象。每个按钮的状态都由 Style 属性决定。下述代码创建了能够用来打开和保存文件的按钮，并包含了一个用来改变窗体背景的 ComboBox 控件。要试用此例，将 Toolbar 控件，ImageList 控件和 ComboBox 控件放置到窗体上，并把代码粘贴到窗体的声明部分。要确保将 ComboBox 直接插入到 Toolbar 控件上。运行此例，单击不同按钮并从组合框中进行选择。

Private Sub Form_Load()
   '为 ImageList 创建对象变量。
   Dim imgX As ListImage

   '将图片加载到 ImageList 控件中。
   Set imgX = ImageList1.ListImages. _
   Add(, "open", LoadPicture("Graphics\bitmaps\tlbr_w95\open.bmp"))
   Set imgX = ImageList1.ListImages. _
   Add(, "save", LoadPicture("Graphics\bitmaps\tlbr_w95\save.bmp"))
   Toolbar1.ImageList = ImageList1

   '为 Toolbar 创建对象变量。
   Dim btnX As Button
   '用 Add 方法将按钮对象添加到 Buttons 集合中。创建
   '每个按钮后，设置 Description 和 ToolTipText 属性。
   Toolbar1.Buttons.Add , , , tbrSeparator
   Set btnX = Toolbar1.Buttons.Add(, "open", , tbrDefault, "open")
   btnX.ToolTipText = "Open File"
   btnX.Description = btnX.ToolTipText
   Set btnX = Toolbar1.Buttons.Add(, "save", , tbrDefault, "save")
   btnX.ToolTipText = "Save File"
   btnX.Description = btnX.ToolTipText
   Set btnX = Toolbar1.Buttons.Add(, , , tbrSeparator)
 
   '下一个按钮具有 Placeholder 属性。ComboBox 控件
   '将被放置在按钮的上方。
   Set btnX = Toolbar1.Buttons.Add(, "combo1", , tbrPlaceholder)
   btnX.Width = 1500 '容纳一个 combobox 的占位符宽度。

   Show '显示窗体以继续配置 ComboBox。

   '配置 ComboBox 控件，使其跟具有 PlaceHolder 样式
   '(key = "combo1") 的 Button 对象在相同位置。
   With Combo1
        .Width = Toolbar1.Buttons("combo1").Width
      .Top = Toolbar1.Buttons("combo1").Top
      .Left = Toolbar1.Buttons("combo1").Left
      .AddItem "Black" '为文本添加颜色。
      .AddItem "Blue"
      .AddItem "Red"
      .ListIndex = 0
   End With

End Sub

Private Sub Form_Resize()
   '配置 ComboBox 控件。
   With Combo1
      .Width = Toolbar1.Buttons("combo1").Width
      .Top = Toolbar1.Buttons("combo1").Top
      .Left = Toolbar1.Buttons("combo1").Left
   End With

End Sub
Private Sub toolbar1_ButtonClick(ByVal Button As Button)
   '用 Key 属性和 SelectCase 语句来指定一个动作。
   Select Case Button.Key
   Case Is = "open"       '打开文件。
      MsgBox "Add code to open file here!"
   Case Is = "save"        '保存文件。
      MsgBox "Add code to save file here!"
   End Select
End Sub

Private Sub Combo1_Click()
   '用 ComboBox 改变窗体的背景。
   Select Case Combo1.ListIndex
   Case 0
      Form1.BackColor = vbBlack
   Case 1
      Form1.BackColor = vbBlue
   Case 2
      Form1.BackColor = vbRed
   End Select
End Sub