问题详述
如果已经在屏幕上打开了若干个窗体，如何使用代码一次性关闭除指定名称之外的所有其他窗体？如果是保留多个指定名称的窗体呢？
专家解答
所有打开的窗体都会添加到Forms集合中，如果要关闭打开的窗体，只需循环Forms集合里的对象，然后逐个关闭除指定名称之外的窗体。不过这里有个比较技巧性的地方，那就是如何循环Forms集合里的对象才能正确关闭所有窗体。
不能使用For i = 0 To Application.forms.count -1或For Each frm In Application.Forms这两种方法，因为Forms集合的索引从零开始。如果按照索引引用窗体，则第一个打开的窗体是Forms(0)，第二个打开的是Forms(1)，依此类推。如果打开Form1，然后打开Form2，则Form2在Forms集合中的索引为Forms(1)。如果关闭Form1，Form2在Forms集合的索引将变为Forms(0)，所以当有窗体打开和关闭时，Application.forms里的对象和索引时刻在变化着，而Application.forms.count的值也是变化的，所以使用上述两种方法都无法正确关闭所有窗体。
由于在任何时候都可以获取到所有打开的窗体的个数，而窗体的索引是从0开始的，而最后一个窗体的序号永远是窗体的个数减1，只要每次都关闭最后那个窗体，则循环所有窗体直到最后一个窗体之后，就能关闭所有打开的窗体，所以使用下面巧妙的方法来实现关闭所有窗体的功能。
Dim intCount As Integer ''用来保存打开窗体的个数
Dim i As Integer ''循环变量
intCount = Application.forms.Count ''将打开窗体的个数保存到intCount变量
For i = intCount - 1 To 0 Step -1 ''从大到小循环所有的窗体
DoCmd.Close acForm, Application.forms(i).Name ''关闭最后那个窗体
Next i
上面的代码实现关闭所有打开窗体的功能，如果要保留指定名称的窗体，则创建一个新的函数并改进一下代码。
Private Function CloseAllForms(Optional rstrDontClose As String)
Dim intCount As Integer ''用来保存打开窗体的个数
Dim i As Integer ''循环变量
intCount = Application.forms.Count ''将打开窗体的个数保存到intCount变量
For i = intCount - 1 To 0 Step -1 ''从大到小循环所有的窗体
If Application.forms(i).Name <> Nz(rstrDontClose) Then ''如果不是指定的窗体则关闭它
DoCmd.Close acForm, Application.forms(i).Name ''关闭最后那个窗体
End If
Next i
End Function
然后再使用下面的代码来调用这个函数，将要保留的窗体名传递过去。
CloseAllForms "窗体2"
程序执行后就会关闭除“窗体2”之外的所有已经打开的窗体。
上面的方法只能指定一个窗体名称，如果需要指定多个窗体不关闭，则需要从传递过来的参数中提取每个窗体的名称，然后按照上述同样的方法进行处理，改进后的代码如下。
Private Function CloseAllForms(Optional rstrDontClose As String)
Dim varName As Variant ''存储窗体名称拆分后的数组变量
Dim strFormName As String
Dim intCount As Integer ''用来保存打开窗体的个数
Dim i As Integer ''外循环变量
Dim j As Integer ''内循环变量
Dim blnDontClose As Boolean ''是否需要保留的窗体的标志
intCount = Application.forms.Count ''将打开窗体的个数保存到intCount变量
varName = Split(rstrDontClose, ",") ''将传递过来的参数按分隔符","拆分到数组varName
For i = intCount - 1 To 0 Step -1 ''从大到小循环所有的窗体
blnDontClose = False
For j = 0 To UBound(varName) ''循环指定名称的所有窗体
If Application.forms(i).Name = Nz(varName(j)) Then ''如果是指定的窗体则设置标志
blnDontClose = True
Exit For
End If
Next
If blnDontClose = False Then
DoCmd.Close acForm, Application.forms(i).Name ''如果不在保留的窗体之列，则关闭窗体
End If
Next i
End Function
再使用下面的方法调用上面的函数，多个窗体名称之间使用“,”符号隔开。
CloseAllForms "窗体2,窗体4"
专家点评
从上面的分析得知，无法使用代码在Forms集合中添加或删除Form对象，系统自动维护Forms集合里的对象和索引，所以如果要引用Forms集合中特定的窗体，最好按窗体名称来引用该窗体，而不是使用索引来引用窗体，因为窗体的集合索引可能随时会改变。
由于包含CloseAllForms "窗体2,窗体4" 这句代码的窗体也是打开的窗体，所以在关闭时也会关闭这个窗体。另外，不管窗体是打开在设计视图、窗体视图、数据表视图还是其他视图，都是属于打开的窗体，如果在设计视图里的窗体还没有保存，则在关闭时会提示是否保存窗体。
对于Access的报表，也可使用类似的方法来处理，只不过，已打开的报表集合是“Reports”，而不是“Forms”。
