进行如下几个步聚:
1.工具->启动->把[显示数据库窗口]前面的勾去掉.
2.新建模块,写入以下代码:
Public Function funcSetBypassPropertyFalse()
Const DB_Boolean As Long = 1
funcChangeProperty "AllowBypassKey", DB_Boolean, False
End Function
Public Function funcSetBypassPropertyTrue()
Const DB_Boolean As Long = 1
funcChangeProperty "AllowBypassKey", DB_Boolean, True
End Function
Public Function funcChangeProperty(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
' 功能:启用或禁用Shift键开启ACCESS程序
' 示例:禁用:Call funcSetBypassPropertyFalse
' 启用:Call funcSetBypassPropertyTrue
Dim dbs As Object, prp As Variant
Const conPropNotFoundError = 3270
Set dbs = CurrentDb
On Error GoTo Change_Err
dbs.Properties(strPropName) = varPropValue
funcChangeProperty = True
Change_Bye:
Exit Function
Change_Err:
If Err = conPropNotFoundError Then 'Property not found.
Set prp = dbs.CreateProperty(strPropName, _
varPropType, varPropValue)
dbs.Properties.Append prp
Resume Next
Else
'Unknown error.
funcChangeProperty = False
Resume Change_Bye
End If
End Function
3.在你选中的窗体上新建两个命令按钮:[禁用Shift键];[启用Shift键].分别在其单击事件中写入以下代码:
[禁用Shift键]:Call funcSetBypassPropertyFalse
[启用Shift键]:Call funcSetBypassPropertyTrue