红尘通用系统提问

登录界面里，“登录”按钮事件：

Private Sub cmdLogon_Click()
On Error GoTo Err_cmdLogon_Click

    Dim rst As New ADODB.Recordset  '登录验证用到的临时记录集
    Dim strSQL As String            '记录集数据来源SQL语句
    Dim strWhere As String          'SQL语句中的Where条件
    Dim Strformname As String       '用户身份验证后打开的窗体（一般为面板窗体）
   
    Strformname = "frmMain"
   
    If IsNull(Me.txtUser) Then
        MsgBox "请输入用户ID或用户名。", vbInformation
        Me.txtUser.SetFocus
       
    ElseIf IsNull(Me.txtPassword) Then
        MsgBox "请输入大小写形式正确的密码。", vbInformation
        Me.txtPassword.SetFocus
    Else
        strSQL = "SELECT * FROM USysUsers"
        '如果用户名输入框中输入的是数字，则认为是使用用户ID登录
        If IsNumeric(Me!txtUser) Then
            strWhere = "[FUserID]=" & CLng(Me!txtUser)
        Else
            strWhere = "[FUserName]='" & Me!txtUser & "'"
        End If
        strSQL = strSQL & " WHERE " & strWhere
        '打开一个以输入的用户名或用户ID作为查询条件的记录集
        rst.Open strSQL, CurrentProject.Connection, adOpenKeyset, adLockReadOnly
        '如果为空则说明用户不存在
        If rst.EOF Then
            MsgBox "该用户不存在。请重新输入正确的ID或者用户名。", vbCritical
            Me!txtUser.SetFocus
            Me!txtUser = Null
        Else
            '用户存在但该用户被禁止登录提示
            If Not Nz(rst!FEnabled, False) Then
                MsgBox "该用户被禁止登录，要启用此帐号请联系管理员。", vbCritical
            Else
                '如果用户存在且未被禁止登录，则进行密码验证（密码进行二进制比较，以区分大小写）
                If StrComp(rst!FPassword, RC4(Nz(Me!txtPassword)), vbBinaryCompare) <> 0 Then
                    Me!txtPassword.SetFocus
                    Me!txtPassword = Null
                    MsgBox "密码错误。请重新输入密码，注意使用正确的大小写形式。", vbCritical
                Else
                    Me.txtUser = Null
                    Me.txtPassword = Null
                    Me.txtUserId = rst!FUserId
                    Me.txtUserName = rst!FUserName
                    Me.txtUserGroup = Nz(rst!FUserGroup)
                    gblnQuitSystem = False
                    '将登录写入操作日志
                    PutOperateLog "用户登录", ""
                    Me.Visible = False
                    gblnQuitSystem = False
                    If FormIsLoaded("frmMain") Then DoCmd.Close acForm, "frmMain"
                    gblnQuitSystem = True
                    DoCmd.OpenForm "frmMain"
                End If
            End If
        End If
        rst.Close
    End If
   
   
Exit_cmdLogon_Click:
    Set rst = Nothing
    Exit Sub
   
Err_cmdLogon_Click:
    MsgBox Me.Name & " cmdLogon_Click" & vbCr & Err.Description, vbCritical
    '写入错误日志
    PutErrorLog acForm, Me.Name, "cmdLogon_Click"
    Resume Exit_cmdLogon_Click
   
End Sub