关于按时间段查询出现的问题

邓老师,你好,这是我的查询和清空的代码,这也是我在这网上下载别人的,你帮我看一下哪块出问题了

Private Sub cmd查询_Click()
On Error GoTo Err_cmd查询_Click

    Dim strWhere As String  '定义条件字符串
   
    strWhere = "" '设定初始值－空字符串
   
    '判断【版号】条件是否有输入的值
    If Not IsNull(Me.版号) Then
        '有输入
        strWhere = strWhere & "([版号] like '*" & Me.版号 & "*') AND "
    End If
    
    '判断【完成时间】条件是否有输入的值，由于有【完成时间开始】【完成时间截止】两个文本框
    '所以要分开来考虑
    If Not IsNull(Me.完成时间开始) Then
        '【完成时间开始】有输入
        strWhere = strWhere & "([完成时间] >= #" & Format(Me.完成时间开始, "yyyy-mm-dd") & "#) AND "
    End If
    If Not IsNull(Me.完成时间截止) Then
        '【完成时间截止】有输入
        strWhere = strWhere & "([完成时间] <= #" & Format(Me.完成时间截止, "yyyy-mm-dd") & "#) AND "
    End If
   
    '如果输入了条件，那么strWhere的最后肯定有" AND "，这是我们不需要的，
    '要用LEFT函数截掉这5个字符。
    If Len(strWhere) > 0 Then
        '有输入条件
        strWhere = Left(strWhere, Len(strWhere) - 5)
    End If
   
    '先在立即窗口显示一下strWhere的值，代码调试完成后可以取消下一句
    Debug.Print strWhere
   
    '让子窗体应用窗体查询
    Me.下雕活查询子窗体.Form.Filter = strWhere
    Me.下雕活查询子窗体.Form.FilterOn = True

Exit_cmd查询_Click:
    Exit Sub

Err_cmd查询_Click:
    MsgBox Err.Description
    Resume Exit_cmd查询_Click
End Sub
Private Sub cmd清除_Click()
   
    '下面这些控件的值要清空
    Me.版号 = Null
    Me.完成时间开始 = Null
    Me.完成时间截止 = Null
   
    Me.下雕活查询子窗体.Requery  '清空之后一样要重新查询
End Sub