【access小品】一打两就--自定义函数编制讲座五

时　间:2011-06-15 00:00:00
作　者:煮江品茶   ID：10802  城市：武汉
摘　要:【Access小品】一打两就--自定义函数编制讲座五
正　文:

　　版友付谦同志问如何导出子窗体中的数据到Excel表中，这个问题有非常多的解法。我想结合这个问题说一下，编写自定义函数时注意其运用的多角度多方面的问题。标题中的“一打两就”是湖北人常用的口头禅，是一石二鸟、一箭双雕的意思。写自定义函数时，要善于拆分功能，使之各个部分能独立的运用。

　　我们知道导出Excel表可以用DoCmd.OutputTo、DoCmd.TransferDatabase、DoCmd.TransferSpreadsheet等方法，这类方法使用中有一个条件，就是必须针对数据表或者查询，不能用ｓｑｌ语句字符串。要想用这类方法，就需要建立查询。于是我们可以写一个如下的函数来导出子窗体中的记录：

Public Function 导出E(frm As Form)
'示例：导出E(me.子窗体.form)
Dim Qdef As QueryDef
Dim ssql As String
Dim strwh As String
ssql = frm.RecordSource
ssql = Trim(ssql)
If Right(ssql, 1) = ";" Then
    ssql = Left(ssql, Len(ssql) - 1)
End If
ssql = "select * from (" & ssql & ") where "
strwh = "True"
If frm.Filter <> "" Then
    strwh = strwh & " and " & frm.Filter
End If
ssql = ssql & strwh
Set Qdef = CurrentDb.CreateQueryDef("TempQ")
Qdef.SQL = ssql
DoCmd.OutputTo acOutputQuery, "TempQ", acFormatXLS
DoCmd.DeleteObject acQuery, "TempQ"
Qdef.Close
Set Qdef = Nothing
End Function

　　这个函数的处理过程中，实际上进行了三个主要步骤，其一是用子窗体的数据源和筛选获得一个SQL语句字符串，其二是创建一个查询，其三是导出Excel表。这三个步骤中的前两个实际上在其他方面也会有运用，比如可以用第一个步骤得到的ｓｑｌ语句字符串进行ADO计算，再比如用第二个步骤创建查询的方法做其他用途。由此我们就可以考虑到，将上面的函数做功能上的解构，形成相对独立的函数。这样我们可以写三个自定义函数如下：

Public Function GetfrmSql(frm as Form) as String
'得到窗体sql语句字符串
Dim ssql As String
Dim strwh As String
ssql = frm.RecordSource
ssql = Trim(ssql)
If Right(ssql, 1) = ";" Then
    ssql = Left(ssql, Len(ssql) - 1)
End If
ssql = "select * from (" & ssql & ") where "
strwh = "True"
If frm.Filter <> "" Then
    strwh = strwh & " and " & frm.Filter
End If
ssql = ssql & strwh
GetfrmSql=ssql
End Function

Public Function CrtQDef(strname As String, strsql As String)
'创建查询
Dim Qdef As QueryDef
Set Qdef = CurrentDb.CreateQueryDef(strname)
Qdef.SQL = strsql
Qdef.Close
Set Qdef = Nothing
End Function

Public Function AccToExl(frm As Form)
'示例：导出E(me.子窗体.form)
Dim Qdef As QueryDef
Set Qdef = CurrentDb.CreateQueryDef("TempQ")
Qdef.SQL = GetfrmSql(frm）
DoCmd.OutputTo acOutputQuery, "TempQ", acFormatXLS
DoCmd.DeleteObject acQuery, "TempQ"
Qdef.Close
Set Qdef = Nothing
End Function

　　通过上面的改造，三个函数均可单独运用于多个方面，也便就起到了一打两就、一石二鸟、一箭双雕的作用了。

上一课 下一课