用VBA自动化Acrobat将PDF文档转换成JPEG格式文件

时　间:2015-04-26 16:37:54
作　者:Big Young   ID：252  城市：襄阳
摘　要:用VBA自动化Acrobat将PDF文档转换成JPEG格式文件。
正　文:

使用本VBA程序将PDF转换为JPEG的文档，系统中必须安装有Adobe Acrobat，在VBE窗口中要添加对Acrobat对象库的引用。完整的函数代码如下：

Public Sub PDF2Jpeg(ByVal strPdfFile As String, ByVal strJpegFile As String)
    Dim app As Acrobat.AcroApp, jso As Object, avDoc As Acrobat.AcroAVDoc, pdDoc As Acrobat.AcroPDDoc
    Set app = CreateObject("AcroExch.App")
    Set avDoc = CreateObject("AcroExch.AVDoc")
    If Not avDoc.Open(strPdfFile, "文档转换") Then
        MsgBox "不能打开指定的 " & strPdfFile & " 文档！", vbOKOnly + vbCritical, "系统信息"
        Set avDoc = Nothing
        Set app = Nothing
        Exit Sub
    End If
    Set pdDoc = avDoc.GetPDDoc()
    Set jso = pdDoc.GetJSObject
    jso.SaveAs strJpegFile, "com.adobe.acrobat.jpeg"
    app.CloseAllDocs
    app.Exit
    Set jso = Nothing
    Set pdDoc = Nothing
    Set avDoc = Nothing
    Set app = Nothing
End Sub

PS：

其他支持的格式:

值                                           可用扩展名
"com.adobe.acrobat.eps"                      eps
"com.adobe.acrobat.html-3-20"                html, htm
"com.adobe.acrobat.html-4-01-css-1-00"       html, htm
"com.adobe.acrobat.jpeg"                     jpeg, jpg, jpe
"com.adobe.acrobat.jp2k"                     jpf, jpx, jp2, j2k, j2c,jpc
"com.adobe.acrobat.doc"                      doc
"com.adobe.acrobat.png"                      png
"com.adobe.acrobat.ps"                       ps
"com.adobe.acrobat.rtf"                      rtf
"com.adobe.acrobat.accesstext"               txt
"com.adobe.acrobat.plain-text"               txt
"com.adobe.acrobat.tiff"                     tiff, tif
"com.adobe.acrobat.xml-1-00"                 xml